initial commit of dotfiles

.add_to.bashrc

@@ -0,0 +1,4 @@
+source "/home/noah/.git-completion"
+alias vsplit='vim -O'
+
+export PATH=$PATH:~/scripts

.gitconfig

@@ -0,0 +1,18 @@
+[user]
+    name = "Noah Hall"
+    email = "noah.t.hall@gmail.com"
+[color]
+    ui = auto
+    interactive = auto
+    status = true
+[alias]
+    stat = status
+    st = status
+    ci = commit
+    co = checkout
+    graph = log --pretty=format:'%h %s' --graph
+    bdates = for-each-ref --sort=-committerdate --format='%(objectname:short) \t %(committerdate:short) \t %(refname:short) \t %(subject)' refs/heads/
+[core]
+	excludesfile = ~/.gitignore_global
+  editor = vim
+  pager = less -r

.gitignore_global

@@ -0,0 +1,21 @@
+#gitignore files
+.gitignore
+
+#files currently being vim'd
+*.swp
+
+#python bytecode
+*.pyc
+
+#compresssed packages
+*.7z
+*.dmg
+*.gz
+*.iso
+*.jar
+*.rar
+*.tar
+*.zip
+
+#random
+*.bak

.tmux.conf

@@ -0,0 +1,29 @@
+# change prefix key
+unbind C-b
+set -g prefix C-a
+bind C-a send-prefix
+# vim-style search in copy mode
+setw -g mode-keys vi
+
+set -g set-titles on
+set -g set-titles-string "#I) #W"
+# default statusbar colors
+set -g status-fg white
+set -g status-bg black
+set -g status-attr default
+# default window title colors
+set-window-option -g window-status-fg white
+set-window-option -g window-status-bg black
+set-window-option -g window-status-attr dim
+# active window title colors
+set-window-option -g window-status-current-fg white
+set-window-option -g window-status-current-bg default
+set-window-option -g window-status-current-attr bright
+# command/message line colors
+set -g message-fg white
+set -g message-bg black
+set -g message-attr bright
+set -g status-left "#[fg=white,bg=black,bright]#H #[default,fg=white,bg=black]|#[default]"
+set -g status-left-length 12
+set -g status-right "#[default,fg=white,bg=black]|#[fg=white,bg=black,bright]%a %d.%m %H:%M#[default]"
+set -g status-right-length 50

.vim/.netrwhist

@@ -0,0 +1,4 @@
+let g:netrw_dirhistmax  =10
+let g:netrw_dirhist_cnt =2
+let g:netrw_dirhist_1='/var/www/noah/mech/media/js'
+let g:netrw_dirhist_2='/var/www/noah/mech/include'

.vim/.vimrc

@@ -0,0 +1,25 @@
+execute pathogen#infect()
+set autoindent
+set smartindent
+set tabstop=2
+set et
+set shiftwidth=2
+set ruler
+syntax on
+set hlsearch
+set incsearch
+set ignorecase
+set smartcase
+set splitbelow
+set splitright
+" set statusline += %{SyntasticStatuslineFlag()}  "syntastic status line stuff
+au BufRead,BufNewFile *.game set filetype=php 
+au BufRead,BufNewFile *.tpl set filetype=smarty
+au BufRead,BufNewFile con.fig set filetype=php 
+au InsertEnter * set nohlsearch 
+au InsertLeave * set hlsearch 
+au BufRead,BufNewFile *.less set filetype=css 
+noremap <Up> <NOP>
+noremap <Down> <NOP>
+noremap <Left> <NOP>
+noremap <Right> <NOP>

.vim/autoload/pathogen.vim

@@ -0,0 +1,328 @@
+" pathogen.vim - path option manipulation
+" Maintainer:   Tim Pope <http://tpo.pe/>
+" Version:      2.2
+
+" Install in ~/.vim/autoload (or ~\vimfiles\autoload).
+"
+" For management of individually installed plugins in ~/.vim/bundle (or
+" ~\vimfiles\bundle), adding `call pathogen#infect()` to the top of your
+" .vimrc is the only other setup necessary.
+"
+" The API is documented inline below.  For maximum ease of reading,
+" :set foldmethod=marker
+
+if exists("g:loaded_pathogen") || &cp
+  finish
+endif
+let g:loaded_pathogen = 1
+
+function! s:warn(msg)
+  if &verbose
+    echohl WarningMsg
+    echomsg a:msg
+    echohl NONE
+  endif
+endfunction
+
+" Point of entry for basic default usage.  Give a relative path to invoke
+" pathogen#incubate() (defaults to "bundle/{}"), or an absolute path to invoke
+" pathogen#surround().  For backwards compatibility purposes, a full path that
+" does not end in {} or * is given to pathogen#runtime_prepend_subdirectories()
+" instead.
+function! pathogen#infect(...) abort " {{{1
+  for path in a:0 ? reverse(copy(a:000)) : ['bundle/{}']
+    if path =~# '^[^\\/]\+$'
+      call s:warn('Change pathogen#infect('.string(path).') to pathogen#infect('.string(path.'/{}').')')
+      call pathogen#incubate(path . '/{}')
+    elseif path =~# '^[^\\/]\+[\\/]\%({}\|\*\)$'
+      call pathogen#incubate(path)
+    elseif path =~# '[\\/]\%({}\|\*\)$'
+      call pathogen#surround(path)
+    else
+      call s:warn('Change pathogen#infect('.string(path).') to pathogen#infect('.string(path.'/{}').')')
+      call pathogen#surround(path . '/{}')
+    endif
+  endfor
+  call pathogen#cycle_filetype()
+  return ''
+endfunction " }}}1
+
+" Split a path into a list.
+function! pathogen#split(path) abort " {{{1
+  if type(a:path) == type([]) | return a:path | endif
+  let split = split(a:path,'\\\@<!\%(\\\\\)*\zs,')
+  return map(split,'substitute(v:val,''\\\([\\,]\)'',''\1'',"g")')
+endfunction " }}}1
+
+" Convert a list to a path.
+function! pathogen#join(...) abort " {{{1
+  if type(a:1) == type(1) && a:1
+    let i = 1
+    let space = ' '
+  else
+    let i = 0
+    let space = ''
+  endif
+  let path = ""
+  while i < a:0
+    if type(a:000[i]) == type([])
+      let list = a:000[i]
+      let j = 0
+      while j < len(list)
+        let escaped = substitute(list[j],'[,'.space.']\|\\[\,'.space.']\@=','\\&','g')
+        let path .= ',' . escaped
+        let j += 1
+      endwhile
+    else
+      let path .= "," . a:000[i]
+    endif
+    let i += 1
+  endwhile
+  return substitute(path,'^,','','')
+endfunction " }}}1
+
+" Convert a list to a path with escaped spaces for 'path', 'tag', etc.
+function! pathogen#legacyjoin(...) abort " {{{1
+  return call('pathogen#join',[1] + a:000)
+endfunction " }}}1
+
+" Remove duplicates from a list.
+function! pathogen#uniq(list) abort " {{{1
+  let i = 0
+  let seen = {}
+  while i < len(a:list)
+    if (a:list[i] ==# '' && exists('empty')) || has_key(seen,a:list[i])
+      call remove(a:list,i)
+    elseif a:list[i] ==# ''
+      let i += 1
+      let empty = 1
+    else
+      let seen[a:list[i]] = 1
+      let i += 1
+    endif
+  endwhile
+  return a:list
+endfunction " }}}1
+
+" \ on Windows unless shellslash is set, / everywhere else.
+function! pathogen#separator() abort " {{{1
+  return !exists("+shellslash") || &shellslash ? '/' : '\'
+endfunction " }}}1
+
+" Convenience wrapper around glob() which returns a list.
+function! pathogen#glob(pattern) abort " {{{1
+  let files = split(glob(a:pattern),"\n")
+  return map(files,'substitute(v:val,"[".pathogen#separator()."/]$","","")')
+endfunction "}}}1
+
+" Like pathogen#glob(), only limit the results to directories.
+function! pathogen#glob_directories(pattern) abort " {{{1
+  return filter(pathogen#glob(a:pattern),'isdirectory(v:val)')
+endfunction "}}}1
+
+" Turn filetype detection off and back on again if it was already enabled.
+function! pathogen#cycle_filetype() " {{{1
+  if exists('g:did_load_filetypes')
+    filetype off
+    filetype on
+  endif
+endfunction " }}}1
+
+" Check if a bundle is disabled.  A bundle is considered disabled if it ends
+" in a tilde or its basename or full name is included in the list
+" g:pathogen_disabled.
+function! pathogen#is_disabled(path) " {{{1
+  if a:path =~# '\~$'
+    return 1
+  elseif !exists("g:pathogen_disabled")
+    return 0
+  endif
+  let sep = pathogen#separator()
+  let blacklist = g:pathogen_disabled
+  return index(blacklist, strpart(a:path, strridx(a:path, sep)+1)) != -1 && index(blacklist, a:path) != 1
+endfunction "}}}1
+
+" Prepend the given directory to the runtime path and append its corresponding
+" after directory.  If the directory is already included, move it to the
+" outermost position.  Wildcards are added as is.  Ending a path in /{} causes
+" all subdirectories to be added (except those in g:pathogen_disabled).
+function! pathogen#surround(path) abort " {{{1
+  let sep = pathogen#separator()
+  let rtp = pathogen#split(&rtp)
+  if a:path =~# '[\\/]{}$'
+    let path = fnamemodify(a:path[0:-4], ':p:s?[\\/]\=$??')
+    let before = filter(pathogen#glob_directories(path.sep.'*'), '!pathogen#is_disabled(v:val)')
+    let after  = filter(reverse(pathogen#glob_directories(path.sep."*".sep."after")), '!pathogen#is_disabled(v:val[0:-7])')
+    call filter(rtp,'v:val[0:strlen(path)-1] !=# path')
+  else
+    let path = fnamemodify(a:path, ':p:s?[\\/]\=$??')
+    let before = [path]
+    let after = [path . sep . 'after']
+    call filter(rtp, 'index(before + after, v:val) == -1')
+  endif
+  let &rtp = pathogen#join(before, rtp, after)
+  return &rtp
+endfunction " }}}1
+
+" Prepend all subdirectories of path to the rtp, and append all 'after'
+" directories in those subdirectories.  Deprecated.
+function! pathogen#runtime_prepend_subdirectories(path) " {{{1
+  call s:warn('Change pathogen#runtime_prepend_subdirectories('.string(a:path).') to pathogen#surround('.string(a:path.'/{}').')')
+  return pathogen#surround(a:path . pathogen#separator() . '{}')
+endfunction " }}}1
+
+" For each directory in the runtime path, add a second entry with the given
+" argument appended.  If the argument ends in '/{}', add a separate entry for
+" each subdirectory.  The default argument is 'bundle/{}', which means that
+" .vim/bundle/*, $VIM/vimfiles/bundle/*, $VIMRUNTIME/bundle/*,
+" $VIM/vim/files/bundle/*/after, and .vim/bundle/*/after will be added (on
+" UNIX).
+function! pathogen#incubate(...) abort " {{{1
+  let sep = pathogen#separator()
+  let name = a:0 ? a:1 : 'bundle/{}'
+  if "\n".s:done_bundles =~# "\\M\n".name."\n"
+    return ""
+  endif
+  let s:done_bundles .= name . "\n"
+  let list = []
+  for dir in pathogen#split(&rtp)
+    if dir =~# '\<after$'
+      if name =~# '{}$'
+        let list +=  filter(pathogen#glob_directories(substitute(dir,'after$',name[0:-3],'').'*[^~]'.sep.'after'), '!pathogen#is_disabled(v:val[0:-7])') + [dir]
+      else
+        let list += [dir, substitute(dir, 'after$', '', '') . name . sep . 'after']
+      endif
+    else
+      if name =~# '{}$'
+        let list +=  [dir] + filter(pathogen#glob_directories(dir.sep.name[0:-3].'*[^~]'), '!pathogen#is_disabled(v:val)')
+      else
+        let list += [dir . sep . name, dir]
+      endif
+    endif
+  endfor
+  let &rtp = pathogen#join(pathogen#uniq(list))
+  return 1
+endfunction " }}}1
+
+" Deprecated alias for pathogen#incubate().
+function! pathogen#runtime_append_all_bundles(...) abort " {{{1
+  if a:0
+    call s:warn('Change pathogen#runtime_append_all_bundles('.string(a:1).') to pathogen#incubate('.string(a:1.'/{}').')')
+  else
+    call s:warn('Change pathogen#runtime_append_all_bundles() to pathogen#incubate()')
+  endif
+  return call('pathogen#incubate', map(copy(a:000),'v:val . "/{}"'))
+endfunction
+
+let s:done_bundles = ''
+" }}}1
+
+" Invoke :helptags on all non-$VIM doc directories in runtimepath.
+function! pathogen#helptags() abort " {{{1
+  let sep = pathogen#separator()
+  for glob in pathogen#split(&rtp)
+    for dir in split(glob(glob), "\n")
+      if (dir.sep)[0 : strlen($VIMRUNTIME)] !=# $VIMRUNTIME.sep && filewritable(dir.sep.'doc') == 2 && !empty(filter(split(glob(dir.sep.'doc'.sep.'*'),"\n>"),'!isdirectory(v:val)')) && (!filereadable(dir.sep.'doc'.sep.'tags') || filewritable(dir.sep.'doc'.sep.'tags'))
+        helptags `=dir.'/doc'`
+      endif
+    endfor
+  endfor
+endfunction " }}}1
+
+command! -bar Helptags :call pathogen#helptags()
+
+" Execute the given command.  This is basically a backdoor for --remote-expr.
+function! pathogen#execute(...) abort " {{{1
+  for command in a:000
+    execute command
+  endfor
+  return ''
+endfunction " }}}1
+
+" Like findfile(), but hardcoded to use the runtimepath.
+function! pathogen#runtime_findfile(file,count) abort "{{{1
+  let rtp = pathogen#join(1,pathogen#split(&rtp))
+  let file = findfile(a:file,rtp,a:count)
+  if file ==# ''
+    return ''
+  else
+    return fnamemodify(file,':p')
+  endif
+endfunction " }}}1
+
+" Backport of fnameescape().
+function! pathogen#fnameescape(string) abort " {{{1
+  if exists('*fnameescape')
+    return fnameescape(a:string)
+  elseif a:string ==# '-'
+    return '\-'
+  else
+    return substitute(escape(a:string," \t\n*?[{`$\\%#'\"|!<"),'^[+>]','\\&','')
+  endif
+endfunction " }}}1
+
+if exists(':Vedit')
+  finish
+endif
+
+let s:vopen_warning = 0
+
+function! s:find(count,cmd,file,lcd) " {{{1
+  let rtp = pathogen#join(1,pathogen#split(&runtimepath))
+  let file = pathogen#runtime_findfile(a:file,a:count)
+  if file ==# ''
+    return "echoerr 'E345: Can''t find file \"".a:file."\" in runtimepath'"
+  endif
+  if !s:vopen_warning
+    let s:vopen_warning = 1
+    let warning = '|echohl WarningMsg|echo "Install scriptease.vim to continue using :V'.a:cmd.'"|echohl NONE'
+  else
+    let warning = ''
+  endif
+  if a:lcd
+    let path = file[0:-strlen(a:file)-2]
+    execute 'lcd `=path`'
+    return a:cmd.' '.pathogen#fnameescape(a:file) . warning
+  else
+    return a:cmd.' '.pathogen#fnameescape(file) . warning
+  endif
+endfunction " }}}1
+
+function! s:Findcomplete(A,L,P) " {{{1
+  let sep = pathogen#separator()
+  let cheats = {
+        \'a': 'autoload',
+        \'d': 'doc',
+        \'f': 'ftplugin',
+        \'i': 'indent',
+        \'p': 'plugin',
+        \'s': 'syntax'}
+  if a:A =~# '^\w[\\/]' && has_key(cheats,a:A[0])
+    let request = cheats[a:A[0]].a:A[1:-1]
+  else
+    let request = a:A
+  endif
+  let pattern = substitute(request,'/\|\'.sep,'*'.sep,'g').'*'
+  let found = {}
+  for path in pathogen#split(&runtimepath)
+    let path = expand(path, ':p')
+    let matches = split(glob(path.sep.pattern),"\n")
+    call map(matches,'isdirectory(v:val) ? v:val.sep : v:val')
+    call map(matches,'expand(v:val, ":p")[strlen(path)+1:-1]')
+    for match in matches
+      let found[match] = 1
+    endfor
+  endfor
+  return sort(keys(found))
+endfunction " }}}1
+
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Ve       :execute s:find(<count>,'edit<bang>',<q-args>,0)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vedit    :execute s:find(<count>,'edit<bang>',<q-args>,0)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vopen    :execute s:find(<count>,'edit<bang>',<q-args>,1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vsplit   :execute s:find(<count>,'split',<q-args>,<bang>1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vvsplit  :execute s:find(<count>,'vsplit',<q-args>,<bang>1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vtabedit :execute s:find(<count>,'tabedit',<q-args>,<bang>1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vpedit   :execute s:find(<count>,'pedit',<q-args>,<bang>1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vread    :execute s:find(<count>,'read',<q-args>,<bang>1)
+
+" vim:set et sw=2:

.vim/bundle/syntastic

@@ -0,0 +1 @@
+Subproject commit 0fcf79514009c0c836b5a4c32ae4719891983fa2

.vim/bundle/vim-fugitive

@@ -0,0 +1 @@
+Subproject commit 0103538d7a8e03c061c031e33459aeaa4cf040ab

.vim/syntax

@@ -0,0 +1,250 @@
+" Vim syntax file
+" Language:	Smarty Templates
+" Maintainer:	Manfred Stienstra manfred.stienstra@dwerg.net
+" Last Change:  Fri Apr 12 10:33:51 CEST 2002 
+" Filenames:    *.tpl
+" URL:		http://www.dwerg.net/download/vim/smarty.vim
+
+" For version 5.x: Clear all syntax items
+" For version 6.x: Quit when a syntax file was already loaded
+if !exists("main_syntax")
+  if version < 600
+    syntax clear
+  elseif exists("b:current_syntax")
+  finish
+endif
+  let main_syntax = 'smarty'
+endif
+
+syn case ignore
+
+runtime! syntax/html.vim
+"syn cluster htmlPreproc add=smartyUnZone
+
+syn keyword smartyTagName capture config_load include include_php
+syn keyword smartyTagName insert if elseif else ldelim rdelim literal
+syn keyword smartyTagName php section sectionelse foreach foreachelse
+syn keyword smartyTagName strip cycle config_load assign counter debug
+syn keyword smartyTagName eval fetch html_checkboxes html_image
+syn keyword smartyTagName html_options html_radios html_select_date
+syn keyword smartyTagName html_select_time html_table mailto
+syn keyword smartyTagName math popup popup_init textformat
+
+syn keyword smartyInFunc ne eq == != > < >= <= === ! % 
+
+syn match smartyProperty contained "file="
+syn match smartyProperty contained "loop="
+syn match smartyProperty contained "name="
+syn match smartyProperty contained "include="
+syn match smartyProperty contained "skip="
+syn match smartyProperty contained "section="
+syn match smartyProperty contained "from="
+syn match smartyProperty contained "item="
+syn match smartyProperty contained "key="
+syn match smartyProperty contained "once="
+syn match smartyProperty contained "global="
+syn match smartyProperty contained "scope="
+syn match smartyProperty contained "script="
+syn match smartyProperty contained "assign="
+syn match smartyProperty contained "start="
+syn match smartyProperty contained "stop="
+syn match smartyProperty contained "max="
+syn match smartyProperty contained "show="
+syn match smartyProperty contained "step="
+syn match smartyProperty contained "var="
+syn match smartyProperty contained "value="
+syn match smartyProperty contained "skip="
+syn match smartyProperty contained "direction="
+syn match smartyProperty contained "print="
+syn match smartyProperty contained "advance="
+syn match smartyProperty contained "delimiter="
+syn match smartyProperty contained "reset="
+syn match smartyProperty contained "output="
+syn match smartyProperty contained "selected="
+syn match smartyProperty contained "options="
+syn match smartyProperty contained "separator="
+syn match smartyProperty contained "labels="
+syn match smartyProperty contained "height="
+syn match smartyProperty contained "width="
+syn match smartyProperty contained "basedir="
+syn match smartyProperty contained "alt="
+syn match smartyProperty contained "href="
+syn match smartyProperty contained "path_prefix="
+syn match smartyProperty contained "values="
+syn match smartyProperty contained "prefix="
+syn match smartyProperty contained "time="
+syn match smartyProperty contained "start_year="
+syn match smartyProperty contained "end_year="
+syn match smartyProperty contained "display_days="
+syn match smartyProperty contained "display_months="
+syn match smartyProperty contained "display_years="
+syn match smartyProperty contained "month_format="
+syn match smartyProperty contained "day_format="
+syn match smartyProperty contained "day_value_format="
+syn match smartyProperty contained "year_as_text="
+syn match smartyProperty contained "reverse_years="
+syn match smartyProperty contained "day_size="
+syn match smartyProperty contained "month_size="
+syn match smartyProperty contained "year_size="
+syn match smartyProperty contained "day_extra="
+syn match smartyProperty contained "month_extra="
+syn match smartyProperty contained "year_extra="
+syn match smartyProperty contained "field_order="
+syn match smartyProperty contained "field_separator="
+syn match smartyProperty contained "month_value_format="
+syn match smartyProperty contained "year_empty="
+syn match smartyProperty contained "month_empty="
+syn match smartyProperty contained "day_empty="
+syn match smartyProperty contained "display_hours="
+syn match smartyProperty contained "display_minutes="
+syn match smartyProperty contained "display_seconds="
+syn match smartyProperty contained "minute_interval="
+syn match smartyProperty contained "second_interval="
+syn match smartyProperty contained "field_array="
+syn match smartyProperty contained "all_extra="
+syn match smartyProperty contained "hour_extra="
+syn match smartyProperty contained "minute_extra="
+syn match smartyProperty contained "second_extra="
+syn match smartyProperty contained "meridian_extra="
+syn match smartyProperty contained "display_meridian="
+syn match smartyProperty contained "use_24_hours="
+syn match smartyProperty contained "cols="
+syn match smartyProperty contained "rows="
+syn match smartyProperty contained "inner="
+syn match smartyProperty contained "caption="
+syn match smartyProperty contained "table_attr="
+syn match smartyProperty contained "th_attr="
+syn match smartyProperty contained "tr_attr="
+syn match smartyProperty contained "td_attr="
+syn match smartyProperty contained "trailpad="
+syn match smartyProperty contained "hdir="
+syn match smartyProperty contained "vdir="
+syn match smartyProperty contained "address="
+syn match smartyProperty contained "text="
+syn match smartyProperty contained "encode="
+syn match smartyProperty contained "cc="
+syn match smartyProperty contained "bcc="
+syn match smartyProperty contained "subject="
+syn match smartyProperty contained "newsgroups="
+syn match smartyProperty contained "followupto="
+syn match smartyProperty contained "extra="
+syn match smartyProperty contained "equation="
+syn match smartyProperty contained "format="
+syn match smartyProperty contained "trigger="
+syn match smartyProperty contained "sticky="
+syn match smartyProperty contained "caption="
+syn match smartyProperty contained "fgcolor="
+syn match smartyProperty contained "bgcolor="
+syn match smartyProperty contained "textcolor="
+syn match smartyProperty contained "capcolor="
+syn match smartyProperty contained "closecolor="
+syn match smartyProperty contained "textfont="
+syn match smartyProperty contained "captionfont="
+syn match smartyProperty contained "closefont="
+syn match smartyProperty contained "textsize="
+syn match smartyProperty contained "captionsize="
+syn match smartyProperty contained "closesize="
+syn match smartyProperty contained "width="
+syn match smartyProperty contained "height="
+syn match smartyProperty contained "left="
+syn match smartyProperty contained "right="
+syn match smartyProperty contained "center="
+syn match smartyProperty contained "above="
+syn match smartyProperty contained "below="
+syn match smartyProperty contained "border="
+syn match smartyProperty contained "offsetx="
+syn match smartyProperty contained "offsety="
+syn match smartyProperty contained "fgbackground="
+syn match smartyProperty contained "bgbackground="
+syn match smartyProperty contained "closetext="
+syn match smartyProperty contained "noclose="
+syn match smartyProperty contained "status="
+syn match smartyProperty contained "autostatus="
+syn match smartyProperty contained "autostatuscap="
+syn match smartyProperty contained "inarray="
+syn match smartyProperty contained "caparray="
+syn match smartyProperty contained "capicon="
+syn match smartyProperty contained "snapx="
+syn match smartyProperty contained "snapy="
+syn match smartyProperty contained "fixx="
+syn match smartyProperty contained "fixy="
+syn match smartyProperty contained "background="
+syn match smartyProperty contained "padx="
+syn match smartyProperty contained "pady="
+syn match smartyProperty contained "fullhtml="
+syn match smartyProperty contained "frame="
+syn match smartyProperty contained "function="
+syn match smartyProperty contained "delay="
+syn match smartyProperty contained "hauto="
+syn match smartyProperty contained "indent="
+syn match smartyProperty contained "indent_first="
+syn match smartyProperty contained "indent_char="
+syn match smartyProperty contained "wrap="
+syn match smartyProperty contained "wrap_char="
+syn match smartyProperty contained "vauto="
+syn match smartyProperty contained "wrap_cut="
+
+
+
+
+syn match smartyConstant "\$smarty" 
+
+syn match smartyDollarSign      contained "\$"
+syn match smartyMaybeDollarSign contained "\([^\\]\|\\\\\)\@<=\$"
+
+syn match smartyVariable      contained "\$\@<=\h\w*"
+syn match smartyVariable      contained "\(\$\h\w*\(\.\|\->\|\[.*\]\(\.\|\->\)\)\)\@<=\w*"
+syn match smartyMaybeVariable contained "\(\(^\|[^\\]\|\\\\\)\$\)\@<=\h\w*"
+
+
+syn match smartyEscapedVariable contained "\\$\h\w*"
+
+syn region smartyInBracket    matchgroup=Constant start=+\[+ end=+\]+ contains=smartyVariable contained
+syn region smartyInBacktick   matchgroup=Constant start=+\`+ end=+\`+ contains=smartyVariable contained
+syn region smartyStringDouble matchgroup=Constant start=+"+  end=+"+  contains=smartyMaybeVariable, smartyInBacktick, smartyMaybeDollarSign contained keepend
+
+syn match smartyGlue "\.\|\->"
+
+
+syn region smartyModifier  matchgroup=Statement start=+|+   end=+\ze:\|\>+
+syn region smartyParameter matchgroup=Statement start=+:+   end=+\s\|}+ contains=smartyVariable, smartyDollarSign, smartyGlue, smartyInBracket, smartyStringDouble
+syn region smartyZone     matchgroup=Statement   start="{"   end="}" contains=smartyParameter, smartyProperty, smartyGlue, smartyModifier, smartyDollarSign, smartyInBracket, smartyStringDouble, smartyVariable, smartyString, smartyBlock, smartyTagName, smartyConstant, smartyInFunc
+syn region smartyComment  matchgroup=Comment   start="{\*" end="\*}"
+
+syn region  htmlString   contained start=+"+ end=+"+ contains=htmlSpecialChar,javaScriptExpression,@htmlPreproc,smartyZone
+syn region  htmlString   contained start=+'+ end=+'+ contains=htmlSpecialChar,javaScriptExpression,@htmlPreproc,smartyZone
+  syn region htmlLink start="<a\>\_[^>]*\<href\>" end="</a>"me=e-4 contains=@Spell,htmlTag,htmlEndTag,htmlSpecialChar,htmlPreProc,htmlComment,javaScript,@htmlPreproc,smartyZone
+
+
+if version >= 508 || !exists("did_smarty_syn_inits")
+  if version < 508
+    let did_smarty_syn_inits = 1
+    command -nargs=+ HiLink hi link <args>
+  else
+    command -nargs=+ HiLink hi def link <args>
+  endif
+
+  HiLink smartyTagName         Function
+  HiLink smartyProperty        Type
+  HiLink smartyComment         Comment
+  HiLink smartyInFunc          Function
+  HiLink smartyBlock           Constant
+  HiLink smartyGlue            Statement
+  HiLink smartyVariable        Identifier
+  HiLink smartyDollarSign      Statement
+  HiLink smartyMaybeVariable   Identifier
+  HiLink smartyMaybeDollarSign Statement
+  HiLink smartyStringDouble    Special
+  HiLink smartyInBracket       PreProc
+  HiLink smartyInBacktick      Statement
+  HiLink smartyModifier        Special
+  delcommand HiLink
+endif 
+
+let b:current_syntax = "smarty"
+
+if main_syntax == 'smarty'
+  unlet main_syntax
+endif
+
+" vim: ts=8

.vimrc

@@ -0,0 +1,22 @@
+execute pathogen#infect()
+set autoindent
+set smartindent
+set tabstop=2
+set et
+set shiftwidth=2
+set ruler
+syntax on
+set hlsearch
+set incsearch
+set ignorecase
+set smartcase
+set splitbelow
+set splitright
+" set statusline += %{SyntasticStatuslineFlag()}  "syntastic status line stuff
+au InsertEnter * set nohlsearch 
+au InsertLeave * set hlsearch 
+au BufRead,BufNewFile *.less set filetype=css 
+noremap <Up> <NOP>
+noremap <Down> <NOP>
+noremap <Left> <NOP>
+noremap <Right> <NOP>